<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
		xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                exclude-result-prefixes="#default">
  <xsl:import href="../../../system/api-v001.xsl" />
  <xsl:import href="../../../felles/komponenter/fritekst/v002/fritekst.xsl" />
  <xsl:import href="../../../felles/komponenter/overskrift/v001/overskrift.xsl" />
  <xsl:import href="../../komponenter/saksinfo/v001/saksinfo.xsl"/>
  <xsl:import href="../../ressurser/indexnumber-v001.xsl"/>
  <xsl:import href="../../ressurser/diverse-v001.xsl"/>

  <xsl:include href="../../../felles/ressurser/output-method-html-v001.xsl" />

  <xsl:template match="/">
     <head>
      <title><xsl:value-of select="/kapittel/tittel"/></title>
      <meta name="redaksjon.navn" content="Okonbok" />
      <meta name="redaksjon.epost" content="okonbok-redaksjon@usit.uio.no" />
      <meta name="keywords" content="Administrative håndbøker, økonomihåndboken" />
    </head>
    <body>
      <xsl:call-template name="sti-og-sokeboks" />
      <xsl:apply-templates />
      <xsl:call-template name="bunnsignatur" />
    </body>
  </xsl:template>

  <xsl:template match="kapittel">
     <xsl:choose>
      <xsl:when test="status = 'ferdig'">
            <xsl:apply-templates/>
      </xsl:when>
      <xsl:otherwise><!-- status = 'utkast' -->
        <xsl:apply-templates select="tittel" />

        <font size="+2" color="red">Dokumentet er under arbeid / revisjon</font>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

  <xsl:template match="status | saksinfo" />   
    
  <xsl:template match="tittel">
    <h1>
      <xsl:if test="not($indexnumber='')"><xsl:value-of select="$indexnumber" /><xsl:text>:</xsl:text>&#160;</xsl:if>
      <xsl:value-of select="." />
    </h1>
  </xsl:template>
 
  <xsl:template match="rutineliste">
    <xsl:if test="not(.='')">
      <ul>
        <xsl:for-each select="./*">
          <li><xsl:apply-templates select="."/></li>    
        </xsl:for-each>
      </ul>
    </xsl:if>
  </xsl:template>

  <xsl:template match="referanse"> 
    <xsl:choose>
      <!-- sjekk på om det refereres til et xmldokument -->
      <xsl:when test="substring(.,string-length(.) - 3, string-length(.))='.xml'">

        <xsl:variable name="doc" select="document(., self::node())" />
        <xsl:choose>
          <xsl:when test="$doc/rutine"> <!-- ekstra test fordi rutine ikke har tittelelement -->
            <a target="nyttvin" href="{.}"><xsl:value-of select="$doc/rutine/rutinenavn" /></a>
          </xsl:when>
          <xsl:when test="$doc//tittel"> 
            <a target="nyttvin" href="{.}"><xsl:value-of select="$doc//tittel" /></a>
          </xsl:when>
          <xsl:otherwise>
            <xsl:text>Dokumentet er passordbeskyttet.&#160;</xsl:text><xsl:if test="normalize-space($currentUser) = ''">(<a href="{.}">logg inn</a>)</xsl:if>
            <!-- fant ikke eller xmldok. er skrivebeskyttet, men skriver ikke ut feil -->
          </xsl:otherwise>
        </xsl:choose>
      </xsl:when>
      <xsl:otherwise>
        <xsl:text>Dokumentet er passordbeskyttet.&#160;</xsl:text><xsl:if test="normalize-space($currentUser) = ''">(<a href="{.}">logg inn</a>)</xsl:if>
        <!-- pekes ikke til et xmldok. men skriver ikke ut feil -->
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>
